[FC][魂斗罗][24合1]

yandagui

真是无聊透顶, 搞个假的合卡哈

游客，如果您要查看本帖隐藏内容请回复

1. ;[FC][精简合卡菜单45_52]
   
2. ;FlameCyclone
   
3. ;2020.03.22
   
4. ;6502 Macroassembler & Simulator 1.2.11
   
5. ;==================================================
   
6. RESET_PORT             = $A000
   
7. MENU_INDEX             = 03
   
8. MENU_RESET             = $F80D
   
9. MENU_NMI               = $E800
   
10. ;==================================================
    
11. MULTICART_TYPE         = 52
    
12. ;==================================================
    
13. Char_Arrow = $3F
    
14. SCROLL_H_VALUE         = 0
    
15. SCROLL_V_VALUE         = 8
    
16. ARROW_X_OFFSET         = $1C ;箭头横坐标
    
17. ARROW_Y_OFFSET         = $27 ;箭头纵坐标
    
18. ITEM_COUNT             = 24  ;节目总数
    
19. SPRITES_ADDR           = $0400
    
20. SPRITES_PAGE           = SPRITES_ADDR / 256
    
21. ;==================================================
    
22. BTN_DELAY              = 30     ;按键重复触发时长
    
23. BTN_SPEED              = 10     ;按键重复触发速度
    
24. ;==================================================
    
25. Data_L                 = $40
    
26. Data_H                 = Data_L + $01
    
27. Data_Count             = Data_H + $01
    
28. ;==================================================
    
29. Sel_Index              = Data_Count + $01
    
30. ;==================================================
    
31. Button_Keep            = Sel_Index + $01
    
32. Button_Once            = Button_Keep+$01
    
33. Button_Temp            = Button_Once+$01
    
34. Button_Buf             = Button_Temp+$01
    
35. Button_Status          = Button_Buf+$01
    
36. ;==================================================
    
37. SEL_PROCESS_SIZE       = SelectGameLength - SelectGame
    
38. Sel_Process_Addr       = $0500
    
39. ;==================================================
    
40. Second_Time            = Button_Status + $02
    
41. Btn_Delay              = Second_Time + $01
    
42. 
    
43. .IF MULTICART_TYPE == 52
    
44. ;========================================
    
45. Sel_Addr_L             = Btn_Delay + 2
    
46. Sel_Addr_H             = Sel_Addr_L + 1
    
47. .ENDIF
    
48. 
    
49. .IF MULTICART_TYPE == 45
    
50. ;========================================
    
51. Rom_Index              = Btn_Delay + 2
    
52. CHR_Addr_L             = Rom_Index + $01
    
53. CHR_Addr_H             = CHR_Addr_L + $01
    
54. PRG_Addr               = CHR_Addr_H + $01
    
55. PRG_Size               = PRG_Addr + $01
    
56. CHR_Size               = PRG_Size + $01
    
57. MIR_Addr               = CHR_Size + $01
    
58. ;========================================
    
59. .ENDIF
    
60. 
    
61. BTN_UP                 = $08
    
62. BTN_DOWN               = $04
    
63. BTN_LEFT               = $02
    
64. BTN_RIGHT              = $01
    
65. BTN_SELECT             = $20
    
66. BTN_START              = $10
    
67. BTN_B                  = $40
    
68. BTN_A                  = $80
    
69. ;==================================================
    
70. SOUND_OPEN             = 1     ;菜单音效
    
71. CUSTOM_MUSIC_OPEN      = 0     ;个性化音乐
    
72. BUTTON_SOUND_OPEN      = 1     ;按键选择列表音效
    
73. ATTRIBUTE_OPEN         = 1     ;属性表开启
    
74. ROM_CHAR_MAP           = 1     ;字符映射
    
75. ;==================================================
    
76. ROM_MIRRIOR_OPEN       = 0     ;启用镜像选择
    
77. ROM_VRAM_OPEN          = 0     ;启用VRAM
    
78. Vram_Data              = $BC00 ;Vram数据地址
    
79. Vram_Addr              = $0200 ;Vram写入地址
    
80. Vram_Size              = $04   ;VRAM大小 * 0x100
    
81. ;==================================================
    
82. Sound_Addr_Init        = $BF00 ;音乐初始化
    
83. Sound_Addr_Play        = $8000 ;音乐播放
    
84. SOUND_BGM              = 29    ;背景音效
    
85. SOUND_BUTTON           = 30    ;选择音效
    
86. SOUND_ENTER            = 34    ;进入音效
    
87. SOUND_ENTER_TIME       = 60    ;进入音效延时
    
88. ;==================================================
    
89. .ORG RESET_PORT
    
90. ;==================================================
    
91. ;程序初始化
    
92. ResetInit:
    
93. CLD
    
94. SEI
    
95. LDX #$FF
    
96. TXS
    
97. LDA #$00
    
98. STA $2000
    
99. STA $2001
    
100. STA $E000
     
101. LDA #$80
     
102. STA $A001
     
103. LDA #$01
     
104. STA $A000
     
105. LDX #$02
     
106. ResetDelayA:
     
107. BIT $2002
     
108. BPL ResetDelayA
     
109. ResetDelayB:
     
110. BIT $2002
     
111. BMI ResetDelayB
     
112. DEX
     
113. BNE ResetDelayA
     
114. 
     
115. LDA #$0F
     
116. STA $4015
     
117. LDA #$C0
     
118. STA $4017
     
119. 
     
120. JSR PaletteClear
     
121. 
     
122. MenuInit
     
123. .IF MULTICART_TYPE == 52
     
124. MenuInitSet:
     
125. LDX #MENU_INDEX
     
126. LDA Rom_Select_Data
     
127. AND #$7F
     
128. STA $6000
     
129. .ENDIF
     
130. 
     
131. .IF MULTICART_TYPE == 45
     
132. LDA #MENU_INDEX
     
133. JSR GetRomPort
     
134. LDX #$00
     
135. MenuInitSet:
     
136. LDA CHR_Addr_L
     
137. STA $6000
     
138. LDA PRG_Addr
     
139. ASL
     
140. STA $6000
     
141. LDA CHR_Addr_H
     
142. ASL
     
143. ASL
     
144. ASL
     
145. ASL
     
146. ORA CHR_Size
     
147. STA $6000
     
148. LDA PRG_Size
     
149. STA $6000
     
150. INX
     
151. BNE MenuInitSet
     
152. .ENDIF
     
153. 
     
154. ;==================================================
     
155. ;RAM清空
     
156. RamClear:
     
157. LDA #$00
     
158. STA $00
     
159. STA $01
     
160. LDX #$08
     
161. LDY #$00
     
162. RamClearWrite:
     
163. STA ($00),Y
     
164. INY
     
165. BNE RamClearWrite
     
166. INC $01
     
167. DEX
     
168. BNE RamClearWrite
     
169. 
     
170. JSR SpriteClear
     
171. JSR VramClear
     
172. JSR ChrSteup
     
173. JSR TextWrite
     
174. JSR TimeWait
     
175. JSR PaletteSet
     
176. 
     
177. .IF ATTRIBUTE_OPEN
     
178. JSR TimeWait
     
179. JSR AttributeSet
     
180. .ENDIF
     
181. 
     
182. JSR ResetScroll
     
183. 
     
184. LDA #BTN_START
     
185. STA Button_Buf
     
186. LDA #$1E
     
187. STA $2001
     
188. 
     
189. JSR NmiDelay
     
190. .IF SOUND_OPEN
     
191. .IF CUSTOM_MUSIC_OPEN
     
192. LDA #SOUND_BGM - 1
     
193. JSR Sound_Addr_Init
     
194. .ENDIF
     
195. .ENDIF
     
196. 
     
197. ;==================================================
     
198. ;循环等待
     
199. WaitLoop:
     
200. JSR NmiDelay
     
201. JSR SelectChange
     
202. JSR SpriteSet
     
203. JMP WaitLoop
     
204. RTS
     
205. 
     
206. ;==================================================
     
207. ;NMI延时
     
208. NmiDelay:
     
209. JSR TimeWait
     
210. LDA #SPRITES_PAGE
     
211. STA $4014
     
212. JSR ResetScroll
     
213. 
     
214. .IF CUSTOM_MUSIC_OPEN
     
215. JSR Sound_Addr_Play
     
216. .ENDIF
     
217. 
     
218. JSR Button_Process
     
219. RTS
     
220. 
     
221. ;==================================================
     
222. ;延时等待
     
223. TimeWait:
     
224. LDA $2002
     
225. BPL TimeWait
     
226. RTS
     
227. 
     
228. ;==================================================
     
229. ;重设滚动
     
230. ResetScroll:
     
231. LDA #$00
     
232. STA $2006
     
233. STA $2006
     
234. LDA #SCROLL_H_VALUE
     
235. STA $2005
     
236. LDA #SCROLL_V_VALUE
     
237. STA $2005
     
238. RTS
     
239. 
     
240. ;==================================================
     
241. ;按键处理
     
242. Button_Process:
     
243. JSR Button_Scan
     
244. LDA Button_Keep
     
245. STA Button_Temp
     
246. JSR Button_Scan
     
247. LDA Button_Keep
     
248. CMP Button_Temp
     
249. BEQ Button_Get_Once
     
250. LDA Button_Buf
     
251. STA Button_Keep
     
252. Button_Get_Once:
     
253. TAY
     
254. EOR Button_Buf
     
255. AND Button_Keep
     
256. STA Button_Once
     
257. STY Button_Buf
     
258. JSR ButtonDelay
     
259. RTS
     
260. ;==================================================
     
261. ;按键扫描
     
262. Button_Scan:
     
263. LDX #$01
     
264. STX $4016
     
265. DEX
     
266. STX $4016
     
267. LDY #$08
     
268. Button_Value:
     
269. LDA $4016
     
270. STA Button_Status
     
271. LSR
     
272. ORA Button_Status
     
273. LSR
     
274. ROL Button_Keep
     
275. DEY
     
276. BNE Button_Value
     
277. RTS
     
278. 
     
279. ;==================================================
     
280. ;按键延时重复
     
281. ButtonDelay:
     
282. LDA Button_Keep
     
283. AND #$EF
     
284. BNE ButtonDelaySet
     
285. LDA #$00
     
286. STA Btn_Delay
     
287. ButtonDelaySet:
     
288. INC Btn_Delay
     
289. LDA Btn_Delay
     
290. CMP #BTN_DELAY + BTN_SPEED
     
291. BCC ButtonDelayEnd
     
292. LDA #BTN_DELAY
     
293. STA Btn_Delay
     
294. LDA Button_Keep
     
295. STA Button_Once
     
296. ButtonDelayEnd:
     
297. RTS
     
298. 
     
299. ;========================================
     
300. ;图形块设置
     
301. ChrSteup:
     
302. LDX #$00
     
303. ChrSteupSetChr:
     
304. STX $8000
     
305. LDA ChrBankData,X
     
306. STA $8001
     
307. INX
     
308. CPX #$06
     
309. BCC ChrSteupSetChr
     
310. 
     
311. .IF ROM_VRAM_OPEN
     
312. LDA #<Vram_Data
     
313. STA Data_L
     
314. LDA #>Vram_Data
     
315. STA Data_H
     
316. LDA #>Vram_Addr
     
317. STA $2006
     
318. LDA #<Vram_Addr
     
319. STA $2006
     
320. LDX #Vram_Size
     
321. LDY #$00
     
322. ChrSteupSetVram:
     
323. LDA (Data_L),Y
     
324. STA $2007
     
325. INY
     
326. BNE ChrSteupSetVram
     
327. INC Data_H
     
328. DEX
     
329. BNE ChrSteupSetVram
     
330. .ENDIF
     
331. 
     
332. RTS
     
333. 
     
334. ;==================================================
     
335. ;精灵清除
     
336. SpriteClear:
     
337. LDX #$00
     
338. LDA #$F8
     
339. SpriteClearWrite:
     
340. STA SPRITES_ADDR,X
     
341. INX
     
342. BNE SpriteClearWrite
     
343. RTS
     
344. 
     
345. ;==================================================
     
346. ;精灵设置
     
347. SpriteSet:
     
348. LDA Sel_Index
     
349. ASL
     
350. ASL
     
351. ASL
     
352. ;ASL
     
353. CLC
     
354. ADC #ARROW_Y_OFFSET
     
355. STA SPRITES_ADDR
     
356. LDA #Char_Arrow
     
357. STA SPRITES_ADDR + 1
     
358. LDA #$00
     
359. STA SPRITES_ADDR + 2
     
360. LDA #ARROW_X_OFFSET
     
361. STA SPRITES_ADDR + 3
     
362. RTS
     
363. 
     
364. ;==================================================
     
365. ;清空PPU内存
     
366. VramClear:
     
367. LDA #$00
     
368. STA $2006
     
369. LDA #$00
     
370. STA $2006
     
371. TAX
     
372. LDY #$30
     
373. LDA #$00
     
374. NameTableClearBeg:
     
375. STA $2007
     
376. INX
     
377. BNE NameTableClearBeg
     
378. DEY
     
379. BNE NameTableClearBeg
     
380. RTS
     
381. 
     
382. ;==================================================
     
383. ;清空调色板
     
384. PaletteClear:
     
385. JSR PaletteAddrSet
     
386. LDA #$0F
     
387. LDX #$00
     
388. PaletteClearWrite:
     
389. STA $2007
     
390. INX
     
391. CPX #$20
     
392. BCC PaletteClearWrite
     
393. RTS
     
394. 
     
395. ;==================================================
     
396. ;设置调色板
     
397. PaletteSet:
     
398. JSR PaletteAddrSet
     
399. LDX #$00
     
400. PaletteSetWrite:
     
401. LDA PaletteData,X
     
402. STA $2007
     
403. INX
     
404. CPX #$20
     
405. BCC PaletteSetWrite
     
406. RTS
     
407. 
     
408. ;==================================================
     
409. ;调色板地址设置
     
410. PaletteAddrSet:
     
411. LDA #$3F
     
412. STA $2006
     
413. LDA #$00
     
414. STA $2006
     
415. RTS
     
416. 
     
417. .IF ATTRIBUTE_OPEN
     
418. ;==================================================
     
419. ;设置属性表
     
420. AttributeSet:
     
421. LDA #$23
     
422. STA $2006
     
423. LDA #$C0
     
424. STA $2006
     
425. LDX #$00
     
426. AttributeSetWrite:
     
427. LDA AttributeData,X
     
428. STA $2007
     
429. INX
     
430. CPX #$40
     
431. BCC AttributeSetWrite
     
432. RTS
     
433. .ENDIF
     
434. 
     
435. ;==================================================
     
436. ;写入文本
     
437. TextWrite:
     
438. LDA #<TextData
     
439. STA Data_L
     
440. LDA #>TextData
     
441. STA Data_H
     
442. LDY #$00
     
443. TextWriteCheckMode:
     
444. LDA (Data_L),Y
     
445. BEQ TextWriteOver
     
446. CMP #$FF
     
447. BEQ TextWriteOver
     
448. AND #$04
     
449. STA $2000
     
450. JSR CheckAddr
     
451. LDA (Data_L),Y
     
452. STA $2006
     
453. JSR CheckAddr
     
454. LDA (Data_L),Y
     
455. STA $2006
     
456. JSR CheckAddr
     
457. LDA (Data_L),Y
     
458. TAX
     
459. JSR CheckAddr
     
460. TextWriteData:
     
461. STX Data_Count
     
462. LDA (Data_L),Y
     
463. 
     
464. .IF ROM_CHAR_MAP
     
465. TAX
     
466. LDA Char_Rom_Map,X
     
467. .ENDIF
     
468. 
     
469. STA $2007
     
470. JSR CheckAddr
     
471. LDX Data_Count
     
472. DEX
     
473. BNE TextWriteData
     
474. JMP TextWriteCheckMode
     
475. TextWriteOver:
     
476. LDA #$00
     
477. STA $2000
     
478. RTS
     
479. ;--------------------------------------------------
     
480. CheckAddr:
     
481. INY
     
482. BNE CheckAddrOver
     
483. INC Data_H
     
484. CheckAddrOver:
     
485. RTS
     
486. 
     
487. ;==================================================
     
488. ;选项切换
     
489. SelectChange:
     
490. LDA Button_Once
     
491. AND #$FF
     
492. BEQ SelectChangeEnd
     
493. SelectChangeSound:
     
494. .IF SOUND_OPEN
     
495. .IF BUTTON_SOUND_OPEN
     
496. JSR ButtonSound
     
497. .ENDIF
     
498. .ENDIF
     
499. SelectInc:
     
500. LDA Button_Once
     
501. AND #BTN_SELECT | BTN_DOWN
     
502. BEQ SelectDec
     
503. LDA Sel_Index
     
504. CMP #ITEM_COUNT - 1
     
505. BCC SelectIncSet
     
506. LDA #$FF
     
507. STA Sel_Index
     
508. SelectIncSet:
     
509. INC Sel_Index
     
510. SelectDec:
     
511. LDA Button_Once
     
512. CMP #BTN_UP
     
513. BNE SelectBeg
     
514. LDA Sel_Index
     
515. BNE SelectDecSet
     
516. LDA #ITEM_COUNT
     
517. STA Sel_Index
     
518. SelectDecSet:
     
519. DEC Sel_Index
     
520. SelectBeg:
     
521. LDA Button_Once
     
522. AND #BTN_LEFT | BTN_B
     
523. BEQ SelectEnd
     
524. LDA #$00
     
525. STA Sel_Index
     
526. SelectEnd:
     
527. LDA Button_Once
     
528. AND #BTN_RIGHT | BTN_A
     
529. BEQ SelectOver
     
530. LDA #ITEM_COUNT - 1
     
531. STA Sel_Index
     
532. SelectOver:
     
533. LDA Button_Once
     
534. CMP #BTN_START
     
535. BNE SelectChangeEnd
     
536. 
     
537. .IF SOUND_OPEN
     
538. JSR TimeWait
     
539. JSR EnterSound
     
540. JSR TimeWait
     
541. JSR SoundClean
     
542. .ENDIF
     
543. 
     
544. JSR TimeWait
     
545. LDA #$00
     
546. STA $2001
     
547. STA $4010
     
548. STA $4011
     
549. STA $4012
     
550. STA $4013
     
551. STA $4015
     
552. JSR PaletteClear
     
553. 
     
554. JMP RomSelect
     
555. SelectChangeEnd:
     
556. RTS
     
557. 
     
558. .IF SOUND_OPEN
     
559. ;========================================
     
560. ;按键音效
     
561. ButtonSound:
     
562. .IF CUSTOM_MUSIC_OPEN
     
563. LDA #SOUND_BUTTON - 1
     
564. JSR Sound_Addr_Init
     
565. RTS
     
566. .ELSE
     
567. LDA #$03
     
568. STA $4015
     
569. LDX #$00
     
570. ButtonSoundWrite:
     
571. LDA ButtonSoundData,X
     
572. STA $4000,X
     
573. INX
     
574. CPX #$04
     
575. BCC ButtonSoundWrite
     
576. RTS
     
577. ButtonSoundData:
     
578. .DB $87,$89,$F0,$00
     
579. .ENDIF
     
580. .ENDIF
     
581. 
     
582. .IF SOUND_OPEN
     
583. ;========================================
     
584. ;进入音效
     
585. EnterSound:
     
586. .IF CUSTOM_MUSIC_OPEN
     
587. LDA #SOUND_ENTER - 1
     
588. JSR Sound_Addr_Init
     
589. LDA #SOUND_ENTER_TIME
     
590. JSR SecondDelay
     
591. RTS
     
592. .ELSE
     
593. LDA #$02
     
594. STA $4015
     
595. LDX #$00
     
596. EnterSoundWrite:
     
597. LDA EnterSoundData,X
     
598. STA $4004,X
     
599. INX
     
600. CPX #$04
     
601. BCC EnterSoundWrite
     
602. LDA #$18
     
603. JSR SecondDelay
     
604. RTS
     
605. EnterSoundData:
     
606. .DB $3F,$9A,$FF,$00
     
607. .ENDIF
     
608. .ENDIF
     
609. 
     
610. .IF SOUND_OPEN
     
611. ;========================================
     
612. ;等待延时
     
613. SecondDelay:
     
614. STA Second_Time
     
615. BEQ SecondDelayEnd
     
616. SecondDelayWait:
     
617. JSR NmiDelay
     
618. LDA Button_Once
     
619. AND #$90
     
620. BNE SecondDelayEnd
     
621. DEC Second_Time
     
622. BNE SecondDelayWait
     
623. SecondDelayEnd:
     
624. RTS
     
625. .ENDIF
     
626. 
     
627. .IF SOUND_OPEN
     
628. ;=================================================
     
629. ;音频清理
     
630. SoundClean:
     
631. LDA #$0B
     
632. STA $4015
     
633. LDA #$00
     
634. STA $4008
     
635. LDA #$0F
     
636. STA $4015
     
637. 
     
638. LDA #$30
     
639. STA $4000
     
640. JSR SoundCleanDelay
     
641. STA $4004
     
642. JSR SoundCleanDelay
     
643. STA $400C
     
644. JSR SoundCleanDelay
     
645. 
     
646. LDA #$7F
     
647. STA $4001
     
648. JSR SoundCleanDelay
     
649. STA $4005
     
650. JSR SoundCleanDelay
     
651. RTS
     
652. 
     
653. SoundCleanDelay:
     
654. NOP
     
655. NOP
     
656. NOP
     
657. NOP
     
658. NOP
     
659. NOP
     
660. NOP
     
661. NOP
     
662. NOP
     
663. NOP
     
664. RTS
     
665. 
     
666. .ENDIF
     
667. 
     
668. 
     
669. .IF MULTICART_TYPE == 52
     
670. ;==================================================
     
671. RomSelect:;选择节目处理
     
672. LDX #$00
     
673. SelectProcessWrite:
     
674. LDA SelectGame,X
     
675. STA Sel_Process_Addr,X
     
676. INX
     
677. CPX #SEL_PROCESS_SIZE
     
678. BCC SelectProcessWrite
     
679. 
     
680. .IF ROM_MIRRIOR_OPEN
     
681. LDX Sel_Index
     
682. LDA Rom_Select_Mirrior,X
     
683. STA $A000
     
684. .ENDIF
     
685. 
     
686. LDA Sel_Index
     
687. ASL
     
688. TAX
     
689. LDA Rom_Select_Data,X
     
690. STA Sel_Addr_H
     
691. INX
     
692. LDA Rom_Select_Data,X
     
693. STA Sel_Addr_L
     
694. LDY #$00
     
695. LDX Sel_Index
     
696. LDA Stage_Data,X
     
697. STA $01C0
     
698. LDA Life_Data,X
     
699. STA $01C1
     
700. LDA Weapon_Data,X
     
701. STA $01C2
     
702. JMP MENU_RESET
     
703. LDA #$00
     
704. JMP Sel_Process_Addr
     
705. 
     
706. ;==================================================
     
707. SelectGame:;选择节目
     
708. STA (Sel_Addr_L),Y
     
709. CPX #MENU_INDEX
     
710. BNE SelectGameEnd
     
711. JMP MENU_RESET
     
712. SelectGameEnd:
     
713. STA $6000
     
714. JMP ($FFFC)
     
715. SelectGameLength:
     
716. .ENDIF
     
717. 
     
718. .IF MULTICART_TYPE == 45
     
719. ;==================================================
     
720. GetRomPort:
     
721. STA Rom_Index
     
722. JSR GetPrgBankIndex
     
723. JSR GetChrBankIndex
     
724. JSR GetPrgSize
     
725. JSR GetChrSize
     
726. LDX Rom_Index
     
727. LDA ROM_Mirroring,X
     
728. STA MIR_Addr
     
729. RTS
     
730. ;----------------------------------------
     
731. WriteMultiPort:
     
732. LDA CHR_Addr_L
     
733. STA $6000
     
734. LDA PRG_Addr
     
735. ASL
     
736. STA $6000
     
737. LDA CHR_Addr_H
     
738. ASL
     
739. ASL
     
740. ASL
     
741. ASL
     
742. ORA CHR_Size
     
743. STA $6000
     
744. LDA PRG_Size
     
745. STA $6000
     
746. RTS
     
747. ;----------------------------------------
     
748. GetPrgBankIndex:
     
749. LDA #$00
     
750. STA PRG_Addr
     
751. LDA Rom_Index
     
752. BEQ GetPrgBankIndexEnd
     
753. LDX #$00
     
754. GetPrgBankIndexBeg:
     
755. LDA PRG_Addr
     
756. CLC
     
757. ADC ROM_PRG_Size,X
     
758. STA PRG_Addr
     
759. INX
     
760. CPX Rom_Index
     
761. BCC GetPrgBankIndexBeg
     
762. GetPrgBankIndexEnd:
     
763. RTS
     
764. ;----------------------------------------
     
765. GetChrBankIndex:
     
766. LDA #$00
     
767. STA CHR_Addr_L
     
768. STA CHR_Addr_H
     
769. LDA Rom_Index
     
770. BEQ GetChrBankIndexEnd
     
771. LDX #$00
     
772. GetChrBankIndexBeg:
     
773. LDA CHR_Addr_L
     
774. CLC
     
775. ADC ROM_CHR_Size,X
     
776. STA CHR_Addr_L
     
777. ADC CHR_Addr_H
     
778. STA CHR_Addr_H
     
779. INX
     
780. CPX Rom_Index
     
781. BCC GetChrBankIndexBeg
     
782. LDX #$00
     
783. GetChrBankIndexSet:
     
784. ASL CHR_Addr_L
     
785. ROL CHR_Addr_H
     
786. INX
     
787. CPX #$03
     
788. BCC GetChrBankIndexSet
     
789. GetChrBankIndexEnd:
     
790. RTS
     
791. ;----------------------------------------
     
792. GetPrgSize:
     
793. LDX Rom_Index
     
794. LDA ROM_PRG_Size,X
     
795. LDX #$00
     
796. GetPrgSizeBeg:
     
797. CMP PRG_Size_Map,X
     
798. BEQ GetPrgSizeSetEnd
     
799. INX
     
800. CPX #$06
     
801. BCC GetPrgSizeBeg
     
802. GetPrgSizeSetEnd:
     
803. LDA PRG_Size_Data,X
     
804. STA PRG_Size
     
805. RTS
     
806. ;----------------------------------------
     
807. GetChrSize:
     
808. LDX Rom_Index
     
809. LDA ROM_CHR_Size,X
     
810. LDX #$00
     
811. GetChrSizeBeg:
     
812. CMP CHR_Size_Map,X
     
813. BEQ GetChrSizeSetEnd
     
814. INX
     
815. CPX #$06
     
816. BCC GetChrSizeBeg
     
817. GetChrSizeSetEnd:
     
818. LDA CHR_Size_Data,X
     
819. STA CHR_Size
     
820. RTS
     
821. 
     
822. ;==================================================
     
823. ;节目选择
     
824. RomSelect:
     
825. LDX #$00
     
826. RomSelectBeg:
     
827. LDA SelectGame,X
     
828. STA Sel_Process_Addr,X
     
829. INX
     
830. CPX #SEL_PROCESS_SIZE
     
831. BCC RomSelectBeg
     
832. LDX Sel_Index
     
833. LDA ROM_Order,X
     
834. CMP #MENU_INDEX
     
835. BNE RomSelectSet
     
836. JMP MENU_RESET
     
837. RomSelectSet:
     
838. JSR GetRomPort
     
839. RomSelfCheck:
     
840. JMP Sel_Process_Addr
     
841. 
     
842. ;==================================================
     
843. ;节目选择处理
     
844. SelectGame:
     
845. LDX #$00
     
846. SelectGameBeg:
     
847. LDA CHR_Addr_L
     
848. STA $6000
     
849. LDA PRG_Addr
     
850. ASL
     
851. STA $6000
     
852. LDA CHR_Addr_H
     
853. ASL
     
854. ASL
     
855. ASL
     
856. ASL
     
857. ORA CHR_Size
     
858. STA $6000
     
859. LDA PRG_Size
     
860. ORA #$C0
     
861. STA $6000
     
862. INX
     
863. BNE SelectGameBeg
     
864. SelectGameSet:
     
865. LDA MIR_Addr
     
866. STA $A000
     
867. JMP ($FFFC)
     
868. SelectGameLength:
     
869. .ENDIF
     
870. 
     
871. ;==================================================
     
872. ;图形块号
     
873. ChrBankData:
     
874. .DB $00,$02,$04,$05,$06,$07
     
875. 
     
876. ;==================================================
     
877. ;调色板数据
     
878. PaletteData:
     
879. .DB $0F,$2A,$2A,$2A,$0F,$25,$25,$25,$0F,$21,$21,$21,$0F,$20,$20,$20
     
880. .DB $0F,$20,$26,$16,$0F,$0F,$0F,$0F,$0F,$0F,$0F,$0F,$0F,$0F,$0F,$0F
     
881. 
     
882. .IF ATTRIBUTE_OPEN
     
883. ;==================================================
     
884. ;属性表数据
     
885. AttributeData:
     
886. .DB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF,$0A,$05,$0A,$05,$09,$0A,$00
     
887. .DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
     
888. .DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
     
889. .DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
     
890. .ENDIF
     
891. 
     
892. .IF ROM_CHAR_MAP
     
893. ;==================================================
     
894. ;字符映射
     
895. Char_Rom_Map:
     
896. .DB $00,$01,$02,$03,$04,$05,$06,$07,$08,$09,$0A,$0B,$0C,$0D,$0E,$0F
     
897. .DB $10,$11,$12,$13,$14,$15,$16,$17,$18,$19,$1A,$1B,$1C,$1D,$1E,$1F
     
898. .DB $00,$21,$22,$23,$24,$25,$26,$27,$28,$29,$2A,$2B,$2C,$2D,$25,$2F
     
899. .DB $01,$02,$03,$04,$05,$06,$07,$08,$09,$0A,$3A,$3B,$3C,$3D,$3E,$3F
     
900. .DB $40,$0B,$0C,$0D,$0E,$0F,$10,$11,$12,$13,$14,$15,$16,$17,$18,$19
     
901. .DB $1A,$1B,$1C,$1D,$1E,$1F,$20,$21,$22,$23,$24,$5B,$5C,$5D,$5E,$5F
     
902. .ENDIF
     
903. 
     
904. ;==================================================
     
905. ;文本数据
     
906. TextData:
     
907. .DB $80,$20,$49
     
908. .STR "CONTRA 24 IN 1"
     
909. .DB $80,$20,$84
     
910. .STR "PUSH U.D OR START BUTTON"
     
911. .DB $80,$20,$C5
     
912. .STR "01.STAGE 1"
     
913. .DB $80,$20,$E5
     
914. .STR "02.STAGE 1 30 LIFE"
     
915. .DB $80,$21,$05
     
916. .STR "03.STAGE 1 30 LIFE S GUN"
     
917. .DB $80,$21,$25
     
918. .STR "04.STAGE 2"
     
919. .DB $80,$21,$45
     
920. .STR "05.STAGE 2 30 LIFE"
     
921. .DB $80,$21,$65
     
922. .STR "06.STAGE 2 30 LIFE S GUN"
     
923. .DB $80,$21,$85
     
924. .STR "07.STAGE 3"
     
925. .DB $80,$21,$A5
     
926. .STR "08.STAGE 3 30 LIFE"
     
927. .DB $80,$21,$C5
     
928. .STR "09.STAGE 3 30 LIFE S GUN"
     
929. .DB $80,$21,$E5
     
930. .STR "10.STAGE 4"
     
931. .DB $80,$22,$05
     
932. .STR "11.STAGE 4 30 LIFE"
     
933. .DB $80,$22,$25
     
934. .STR "12.STAGE 4 30 LIFE S GUN"
     
935. .DB $80,$22,$45
     
936. .STR "13.STAGE 5"
     
937. .DB $80,$22,$65
     
938. .STR "14.STAGE 5 30 LIFE"
     
939. .DB $80,$22,$85
     
940. .STR "15.STAGE 5 30 LIFE S GUN"
     
941. .DB $80,$22,$A5
     
942. .STR "16.STAGE 6"
     
943. .DB $80,$22,$C5
     
944. .STR "17.STAGE 6 30 LIFE"
     
945. .DB $80,$22,$E5
     
946. .STR "18.STAGE 6 30 LIFE S GUN"
     
947. .DB $80,$23,$05
     
948. .STR "19.STAGE 7"
     
949. .DB $80,$23,$25
     
950. .STR "20.STAGE 7 30 LIFE"
     
951. .DB $80,$23,$45
     
952. .STR "21.STAGE 7 30 LIFE S GUN"
     
953. .DB $80,$23,$65
     
954. .STR "22.STAGE 8"
     
955. .DB $80,$23,$85
     
956. .STR "23.STAGE 8 30 LIFE"
     
957. .DB $80,$23,$A5
     
958. .STR "24.STAGE 8 30 LIFE S GUN"
     
959. .DB $FF
     
960. 
     
961. .IF MULTICART_TYPE == 52
     
962. ;==================================================
     
963. ;ROM选择数据
     
964. Rom_Select_Data:
     
965. ;;;;;WMCCSBPP
     
966. ;W: 禁用合卡寄存器并启用RAM
     
967. ;M: CHR 块容量 (0=256KB   1=128KB)
     
968. ;C: CHR 块选择 (位1,0)
     
969. ;S: PRG 块容量 (0=256KB   1=128KB)
     
970. ;B: CHR + PRG 高位(位2)
     
971. ;P: PRG 块选择 (位1,0)
     
972. .DB @11001000   ;001
     
973. .DB @11011001   ;002
     
974. .DB @11101010   ;003
     
975. .DB @11111011   ;004
     
976. .DB @11001100   ;005
     
977. .DB @11011101   ;006
     
978. .DB @11101110   ;007
     
979. .DB @11111111   ;008
     
980. .ENDIF
     
981. 
     
982. ;==================================================
     
983. ;镜像 01:水平 00:垂直
     
984. .IF ROM_MIRRIOR_OPEN
     
985. Rom_Select_Mirrior:
     
986. .DB $00 ;1
     
987. .DB $00 ;2
     
988. .DB $00 ;3
     
989. .DB $00 ;4
     
990. .DB $00 ;5
     
991. .DB $00 ;6
     
992. .DB $00 ;7
     
993. .DB $00 ;8
     
994. .ENDIF
     
995. 
     
996. .IF MULTICART_TYPE == 45
     
997. ;========================================
     
998. CHR_Size_Map:
     
999. .DB $01,$02,$04,$08,$10,$20
     
1000. CHR_Size_Data:
      
1001. .DB $0A,$0B,$0C,$0D,$0E,$0F
      
1002. ;----------------------------------------
      
1003. PRG_Size_Map:
      
1004. .DB $01,$02,$04,$08,$10,$20
      
1005. PRG_Size_Data:
      
1006. .DB $3E,$3C,$38,$30,$20,$00
      
1007. ;========================================
      
1008. ROM_PRG_Size:
      
1009. .DB $08,$08,$08,$08,$08,$08,$08,$08
      
1010. ROM_CHR_Size:
      
1011. .DB $10,$10,$10,$10,$10,$10,$10,$10
      
1012. ;镜像 01:水平 00:垂直
      
1013. ROM_Mirroring:
      
1014. .DB $00,$00,$00,$00,$00,$00,$00,$00
      
1015. ;选择序号索引
      
1016. ROM_Order:
      
1017. .DB $00,$01,$02,$03,$04,$05,$06,$07
      
1018. .ENDIF
      
1019. 
      
1020. 
      
1021. Stage_Data:
      
1022. .DB 0,0,0,1,1,1,2,2,2,3,3,3,4,4,4,5,5,5,6,6,6,7,7,7
      
1023. Life_Data:
      
1024. .DB 2,29,29,2,29,29,2,29,29,2,29,29,2,29,29,2,29,29,2,29,29,2,29,29
      
1025. Weapon_Data:
      
1026. .DB $00,$00,$13,$00,$00,$13,$00,$00,$13,$00,$00,$13,$00,$00,$13,$00,$00,$13,$00,$00,$13,$00,$00,$13

复制代码

keysea

感谢楼主分享

adsl9646

强大{:4_97:}

lelehehe

感谢分享！

afti

好强大的合集

wsz7257

爱玩魂斗罗。

wincyd

统一收藏先

tonyowen123

感谢分享！

liuqi459120528

怎么个假的啊

ssxe

非常强大的合集

she370192822

感谢{:4_118:}

g00dgame

我看到了直接就有 30life 的 版本，哈哈！感谢楼主分享！

xuxiaoxin850127

谢谢分享！

陈联峰

感谢大佬的分享，非常感谢！！

yxcqr

哈哈，确实无聊

meiguo110

谢谢兄弟分享~~

两指琴魔

这个应该就是魂斗罗一袋

pso2001dc

辛苦谢谢

zhaoyunchun

谢谢分享

mslug2

多谢分享！！